# Maintainer: 
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

pkgname=haddock
pkgver=2.10.0
pkgrel=1
pkgdesc="Tool for generating documentation for Haskell libraries"
url="http://hackage.haskell.org/package/haddock"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=('alex' 'happy')
depends=('ghc=7.4.1-2' 'haskell-xhtml=3000.2.0.5-2' 'haskell-ghc-paths=0.1.0.8-7') # 'haskell-mtl'
install=$pkgname.install
source=("http://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('d107dba15e8aee5abcb540b818b5dcb8ced98bae7d0714f50192dba26cadb410')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  
  # These doesn't make haddock work for ghc 7.4.1
  #sed -i 's:ghc >= 7.2 && < 7.4:ghc:' haddock.cabal
  #sed -i 's:base >= 4.3 && < 4.5:base:' haddock.cabal
  #sed -i 's:#elif __GLASGOW_HASKELL__ == 703:#elif __GLASGOW_HASKELL__ == 704:' src/Haddock/InterfaceFile.hs

  runhaskell Setup configure -O -p --enable-split-objs --enable-shared --prefix=/usr \
    --docdir=/usr/share/doc/"$pkgname" --libsubdir=\$compiler/site-local/\$pkgid
  runhaskell Setup build
  runhaskell Setup haddock
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  
  install -Dm744 register.sh "$pkgdir/usr/share/haskell/$pkgname/register.sh"
  install -m744 unregister.sh "$pkgdir/usr/share/haskell/$pkgname/unregister.sh"
  install -dm755 "$pkgdir/usr/share/doc/ghc/html/libraries"
  ln -s "/usr/share/doc/$pkgname/html" "$pkgdir/usr/share/doc/ghc/html/libraries/$pkgname"
  runhaskell Setup copy --destdir="$pkgdir"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  rm -f "$pkgdir/usr/share/doc/$pkgname/LICENSE"
  mv "$pkgdir/usr/bin/haddock" "$pkgdir/usr/bin/haddock-cabal"
}