# $Id: PKGBUILD 116017 2014-07-20 07:10:22Z ttoepper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>

pkgname=i3lock
pkgver=2.6
pkgrel=1
pkgdesc="An improved screenlocker based upon XCB and PAM"
arch=('i686' 'x86_64')
url="http://i3wm.org/i3lock/"
license=('MIT')
groups=("i3")
depends=('xcb-util-image' 'libev' 'cairo' 'libxkbcommon-x11')
options=('docs')
backup=("etc/pam.d/i3lock")
source=("http://i3wm.org/i3lock/$pkgname-$pkgver.tar.bz2"
        "http://i3wm.org/i3lock/$pkgname-$pkgver.tar.bz2.asc")
md5sums=('46870f347f474a894ec8044717b4d925' 'SKIP')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  
  # Fix ticket FS#31544, sed line taken from gentoo
  sed -i -e 's:login:system-auth:' i3lock.pam

  make
  gzip i3lock.1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  
  install -Dm644 i3lock.1.gz ${pkgdir}/usr/share/man/man1/i3lock.1.gz
  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  make clean
}

# vim:set ts=2 sw=2 et: