# $Id: PKGBUILD 106888 2014-03-09 13:16:31Z andrea $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Zuf <kontakt.zuf@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>

pkgname=kdenlive
pkgver=0.9.6
pkgrel=4
pkgdesc="A non-linear video editor for Linux"
arch=('i686' 'x86_64')
# http://download.kde.org/stable/kdenlive/
url="http://www.kdenlive.org/"
license=('GPL')
depends=('kdebase-runtime' 'mlt' 'qjson' 'libqzeitgeist')
makedepends=('automoc4' 'cmake' 'gettext' 'mesa' 'glu')
optdepends=('recordmydesktop: screen capture'
	    'dvdauthor: dvd creation'
	    'dvgrab: firewire capture'
	    'xine-ui: dvd preview'
	    'cdrkit: dvd iso image creation')
install=kdenlive.install
options=('docs')
source=(http://download.kde.org/stable/kdenlive/$pkgver/src/kdenlive-$pkgver.tar.bz2
	"FS37617.patch::http://quickgit.kde.org/?p=kdenlive.git&a=commitdiff&h=d049b327afc02b499266b5c895b13e438490b7c0&o=plain")
md5sums=('3bd3a511b860490acc367e7c9d7ffa43'
         '672edd6399a4d5e80937f61547490038')

prepare() {
  cd ${srcdir}/kdenlive-${pkgver}
  patch -p1 <$srcdir/FS37617.patch
}

build() {
  export LDFLAGS="$LDFLAGS -lX11"
  cd "${srcdir}"
  mkdir -p build
  cd build
  cmake ../kdenlive-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=/usr/lib \
    -DLINK_LIBRARIES=-lX11 \
    -DWITH_Nepomuk=OFF
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}