# $Id: PKGBUILD 105979 2014-02-20 12:14:35Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Unknown47 <unknown47r@gmail.com>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=libfm
pkgver=1.2.0
pkgrel=3
pkgdesc='Library for file management'
url='http://pcmanfm.sourceforge.net/'
arch=('i686' 'x86_64')
license=('GPL')
groups=('lxde')
depends=('gtk2' 'menu-cache' 'udisks' 'desktop-file-utils' 'libexif')
makedepends=('intltool' 'gtk-doc')
replaces=('lxshortcut')
provides=('lxshortcut')
conflicts=('lxshortcut')
install=libfm.install
source=(http://downloads.sourceforge.net/pcmanfm/libfm-$pkgver.tar.xz)
md5sums=('07d1361bc008db46b0fd4c775f5696de')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --enable-udisks \
    --with-gnu-ld
  make LDFLAGS+=' -lgobject-2.0 -lglib-2.0'
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # Temporary fix to FS#32361
  rm -rf "$pkgdir"/usr/include/libfm
  mv "$pkgdir"/usr/include/libfm-1.0/ "$pkgdir"/usr/include/libfm
}