# $Id: PKGBUILD 106113 2014-02-23 10:33:19Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: Padfoot <padfoot@exemail.com.au>

pkgname=lightdm-gtk3-greeter
pkgver=1.8.1
pkgrel=2
epoch=1
pkgdesc='GTK+ greeter for LightDM'
arch=('i686' 'x86_64')
url='https://launchpad.net/lightdm-gtk-greeter'
license=('GPL3' 'LGPL3')
depends=('gtk3' 'lightdm')
makedepends=('exo' 'gnome-doc-utils' 'gobject-introspection' 'intltool')
provides=("${pkgname/3/}")
conflicts=("${pkgname/3/2}")
backup=('etc/lightdm/lightdm-gtk-greeter.conf')
install="${pkgname/3/}.install"
source=("https://launchpad.net/${pkgname/3/}/${pkgver%.?}/${pkgver}/+download/${pkgname/3/}-${pkgver}.tar.gz"
        'session-preselection.patch')
sha256sums=('dac5ce9ac54a6b3c1ef9f9cc056f13f01352c2a897c5bed11e52505132610bab'
            'f7fad1e4b563ddc3f9035d15defcc87c57e2dd7c290aa78808c0a54bb766d94b')

prepare() {
  cd ${pkgname/3/}-${pkgver}

  patch -Np0 -i ../session-preselection.patch
}

build() {
  cd ${pkgname/3/}-${pkgver}

  ./configure --prefix='/usr' --sbindir='/usr/bin' --sysconfdir='/etc' --libexecdir='/usr/lib/lightdm' --disable-static
  make
}

package() {
  cd ${pkgname/3/}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: