# $Id: PKGBUILD 95018 2013-08-03 12:52:23Z bpiotrowski $
# Maintainer:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=lxsession
pkgver=0.4.6.1
pkgrel=1
epoch=1
pkgdesc='Lightweight X11 session manager'
arch=('i686' 'x86_64')
url="http://lxde.org/"
license=('GPL2')
groups=('lxde')
depends=('gtk2' 'dbus')
makedepends=('pkgconfig' 'intltool')
replaces=('lxde-settings-daemon' 'lxsession-lite')
conflicts=('lxsession-lite' 'lxde-settings-daemon')
source=(http://downloads.sourceforge.net/lxde/$pkgname-$pkgver.tar.gz
        lxsession-0.4.6.1-logind-support.patch)
md5sums=('e456b64c5ab3652a4dec661ec706dc6e'
         'd99fb337cba343306df71c85034def3b')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../lxsession-0.4.6.1-logind-support.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure --sysconfdir=/etc --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install 
}