# $Id: PKGBUILD 44959 2011-04-13 12:32:32Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=medit
pkgver=1.0.2
pkgrel=1
pkgdesc="A GTK text editor"
arch=('i686' 'x86_64')
url="http://mooedit.sourceforge.net"
options=('!emptydirs')
license=('GPL')
depends=('pygtk' 'libxml2' 'pcre' 'libsm' 'python2' 'gtk2' 'gcc-libs')
optdepends=('ctags')
makedepends=(pkgconfig perlxml intltool gcc-objc)
install=medit.install
source=(http://downloads.sourceforge.net/mooedit/medit-$pkgver.tar.bz2
	capsule.diff)
md5sums=('331701a1e0255ec3cd1899c7a6f6818b'
         'd3386ca02ba598c73c581bf983a15f23')

build() {
  cd $srcdir/medit-$pkgver
  export PYTHON=/usr/bin/python2
#  patch -Np1 -i $srcdir/capsule.diff
  [ -f Makefile ] || ./configure --prefix=/usr
  make
}

package() {
  cd $srcdir/medit-$pkgver
  make DESTDIR=${pkgdir} install
  cd ${pkgdir}/usr/share/medit-1/language-specs
  sed -i "s|*.sh|*.sh;PKGBUILD|" sh.lang
  rm -rf $pkgdir/usr/share/mime
  rm -rf $pkgdir/usr/share/icons/hicolor/icon-theme.cache
}