# $Id: PKGBUILD 66225 2012-02-23 05:01:23Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Markus Härer <markus.haerer@gmx.net>

pkgname=mysql++
pkgver=3.1.0
pkgrel=3
pkgdesc="A C++ wraper for MySQLs C API"
arch=("i686" "x86_64")
url="http://tangentsoft.net/mysql++/"
license=("LGPL" "custom")
depends=("libmysqlclient")
options=('docs')
source=("http://tangentsoft.net/mysql++/releases/$pkgname-$pkgver.tar.gz"
	"mysql++-fix-cstring.patch"
	"mysql++-fix-size_t.patch")
md5sums=('d92769cc579b87a60e58a77099cc4f0e'
         '72f85a1bdba9d5285f0baf1d973033f8'
         '6dcfbf06072b81cf27530ca9a0df8a8e')

build() {
  unset LDFLAGS
  cd "$srcdir/$pkgname-$pkgver/"
  patch -p1 <$srcdir/mysql++-fix-cstring.patch
  patch -p1 <$srcdir/mysql++-fix-size_t.patch
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver/"
  make DESTDIR="$pkgdir" install

  #install docs
  mkdir -p $pkgdir/usr/share/doc/mysql++
  cp -r doc/html $pkgdir/usr/share/doc/mysql++
  cp -r doc/pdf $pkgdir/usr/share/doc/mysql++

  #install doc licence
  install -Dm0644 doc/userman/LICENSE.txt $pkgdir/usr/share/licenses/mysql++/LICENSE
}