# $Id: PKGBUILD 44312 2011-04-05 15:06:23Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Krzysztof Raczkowski <raczkow@gmail.com>

pkgname=open-vm-tools-modules
pkgver=2011.03.28
_pkgsubver=387002
pkgrel=1
pkgdesc="The Open Virtual Machine Tools (open-vm-tools) are the open source implementation of VMware Tools."
arch=('i686' 'x86_64')
url="http://open-vm-tools.sourceforge.net/"
license=('GPL')
makedepends=('libdnet' 'icu' 'uriparser' 'kernel26-headers')
depends=("kernel26")
install=$pkgname.install
source=(http://easynews.dl.sourceforge.net/sourceforge/open-vm-tools/open-vm-tools-$pkgver-${_pkgsubver}.tar.gz)
md5sums=('a9c72ab0b8f7778d444e69e9d3b95527')

build() {
  cd "$srcdir/open-vm-tools-${pkgver}-${_pkgsubver}"
  sed -i 's#-lproc-3.2.7#-lproc-3.2.8#' configure
  [ $NOEXTRACT -eq 1 ] || ./configure --prefix=/usr
  (cd modules && make modules)
}

package() {
  _kernver=`pacman -Q kernel26 | cut -d . -f 3 | cut -f 1 -d -`
  depends=("kernel26>=2.6.${_kernver}" "kernel26<2.6.`expr ${_kernver} + 1`")
  KERNEL_VERSION="2.6.${_kernver}-ARCH"
  msg "Kernel = $KERNEL_VERSION"

  cd "$srcdir/open-vm-tools-${pkgver}-${_pkgsubver}"
  mkdir -p $pkgdir/lib/modules/$KERNEL_VERSION/misc/
  for MOD in `find -type f -name '*.ko'`; do
    install -D -m644 $MOD $pkgdir/lib/modules/$KERNEL_VERSION/misc/
  done
  sed -i -e "s/KERNEL_VERSION='.*'/KERNEL_VERSION='$KERNEL_VERSION'/" $startdir/$pkgname.install
}