# $Id: PKGBUILD 99543 2013-10-29 12:13:00Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>

pkgname=passenger
pkgver=4.0.21
pkgrel=1
pkgdesc="mod_rails passenger"
arch=('i686' 'x86_64')
url="http://www.modrails.com"
#http://rubyforge.org/frs/?group_id=5873
license=('GPL')
depends=('ruby' 'ruby-rack' 'curl')
makedepends=('apache')
install=passenger.install
options=('!emptydirs')
source=($pkgname-$pkgver.tar.gz::https://github.com/FooBarWidget/passenger/archive/release-$pkgver.tar.gz)
md5sums=('200ba8636baa06c9a44d30c7bbb50ac3')

prepare() {
  cd $srcdir/passenger-release-$pkgver
  sed -i '1,1i#include <stdint.h>' \
    ext/common/Utils/MD5.cpp \
    ext/common/Logging.cpp \
    ext/common/Utils/StrIntUtils.cpp \
    ext/common/Utils.cpp \
    ext/common/ApplicationPool2/AppTypes.cpp \
    ext/boost/libs/thread/src/pthread/once.cpp \
    ext/boost/libs/thread/src/pthread/once_atomic.cpp \
    ext/boost/libs/thread/src/pthread/thread.cpp \
    ext/boost/atomic/atomic.hpp
}

build(){
  cd $srcdir/passenger-release-$pkgver
  ./bin/passenger-install-apache2-module -a
  rake nginx
}

package() {
  cd $srcdir/passenger-release-$pkgver

  mkdir -p $pkgdir/usr/lib/passenger/
  cp -R * $pkgdir/usr/lib/passenger/

  mkdir -p $pkgdir/usr/lib/httpd/modules
  ln -sf /usr/lib/passenger/buildout/apache2/mod_passenger.so $pkgdir/usr/lib/httpd/modules/mod_passenger.so
}