# $Id: PKGBUILD 46331 2011-05-05 10:45:23Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Douglas Soares de Andrade <dsa@aur.archlinux.org>
# Contributor: Benjamin Andresen <benny@klapmuetz.org>
# Contributor: bekks <eduard.warkentin@gmx.de>

pkgname=pgadmin3
pkgver=1.12.3
_realver=1.12.3
pkgrel=1
pkgdesc="A comprehensive design and management interface for PostgreSQL database"
arch=('i686' 'x86_64')
url="http://www.pgadmin.org"
license=('custom')
depends=('wxgtk' 'postgresql-libs>=8.4.1' 'libxslt')
makedepends=('libpqxx' 'krb5')
source=(ftp://ftp.de.postgresql.org/pub/packages/databases/PostgreSQL/pgadmin3/release/v${_realver}/src/pgadmin3-${_realver}.tar.gz
	pgadmin3.desktop)
md5sums=('0ff7a970a14757ee951a4e8b1a246a70'
         'd07ba4df54baead30b66d19d7450bcad')

build() {
    cd $srcdir/pgadmin3-${_realver}
    unset LDFLAGS
    [ $NOEXTRACT -eq 1 ] || ./configure --prefix=/usr
    make
}

package() {
    cd $srcdir/pgadmin3-${_realver}
    make DESTDIR=$pkgdir/ install

    install -D -m 644 i18n/$pkgname.lng $pkgdir/usr/share/pgadmin3/i18n
    install -D -m 644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE

    mkdir -p $pkgdir/usr/share/pgadmin3/pixmaps/
    mkdir -p $pkgdir/usr/share/applications/

    install -D -m 644 pgadmin/include/images/pgAdmin3.ico $pkgdir/usr/share/pgadmin3/pixmaps/pgAdmin3.ico
    install -D -m 644 $srcdir/pgadmin3.desktop $pkgdir/usr/share/applications/
}