# $Id: PKGBUILD 108523 2014-03-27 18:03:37Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: Gabor Nyekhelyi (n0gabor) <n0gabor@vipmail.hu>

pkgname=pitivi
pkgver=0.93
pkgrel=3
pkgdesc="Editor for audio/video projects using the GStreamer framework"
arch=('i686' 'x86_64')
url="http://www.pitivi.org/"
license=('LGPL')
depends=('clutter-gtk' 'gnonlin' 'gst-editing-services' 'gst-plugins-good' 'gst-python'
         'libnotify' 'python2-gobject' 'python2-numpy'
         'gnome-icon-theme' 'desktop-file-utils' 'clutter-gst')
makedepends=('intltool' 'itstool')
optdepends=('frei0r-plugins: additional video effects, clip transformation feature'
            'gst-libav: additional multimedia codecs'
            'gst-plugins-bad: additional multimedia codecs'
            'gst-plugins-ugly: additional multimedia codecs'
            'gnome-desktop: file thumbnails provided by GNOME'\''s thumbnailers')
install=$pkgname.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/$pkgver/$pkgname-$pkgver.tar.xz)
md5sums=('27fa7e560b6da0cc8f83466c1346b96e')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  export PYTHON=python2
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
}