# $Id: PKGBUILD 110741 2014-05-06 01:07:19Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Clément Démoulins <clement@archivel.fr>
# Contributor: Fazlul Shahriar <fshahriar@gmail.com>

pkgname=(python-coverage python2-coverage)
pkgver=3.7.1
pkgrel=3
pkgdesc="A tool for measuring code coverage of Python programs"
arch=('i686' 'x86_64')
url="http://nedbatchelder.com/code/coverage/"
license=('BSD')
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-mock' 'python2-mock' 'python-nose' 'python2-nose')
source=("http://pypi.python.org/packages/source/c/coverage/coverage-$pkgver.tar.gz")
md5sums=('c47b36ceb17eaff3ecfab3bcd347d0df')

prepare() {
  cp -a coverage-$pkgver{,-py2}
}

build() {
  cd "$srcdir/coverage-$pkgver"
  python3 setup.py build

  cd "$srcdir/coverage-$pkgver-py2"
  python2 setup.py build
}

check() {
  cd "$srcdir/coverage-$pkgver"
  #python3 igor.py zip_mods install_egg remove_extension
  #python3 igor.py test_with_tracer py
  #python3 setup.py --quiet build_ext --inplace
  #python3 igor.py test_with_tracer c
}

package_python-coverage() {
  depends=('python')

  cd coverage-$pkgver
  python3 setup.py install --root="$pkgdir" --optimize=1
}

package_python2-coverage() {
  depends=('python2')

  cd coverage-$pkgver
  python2 setup.py install --root="$pkgdir" --optimize=1

  mv "$pkgdir/usr/bin/coverage" "$pkgdir/usr/bin/coverage2"
}