# $Id: PKGBUILD 98558 2013-10-14 02:55:13Z fyan $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Thomas S Hatch <thatch45@gmail.com>
# Contributor: Jelle van der Waa <jelle@vdwaa.nl>

pkgbase=python-pymongo
pkgname=('python-pymongo' 'python2-pymongo')
pkgver=2.6.3
pkgrel=1
pkgdesc='Python driver for MongoDB'
arch=('x86_64' 'i686')
license=('APACHE')
url='http://pypi.python.org/pypi/pymongo/'
makedepends=('python-setuptools' 'python2-setuptools')
source=("http://pypi.python.org/packages/source/p/pymongo/pymongo-$pkgver.tar.gz")

build() {
  cd "$srcdir"

  cp -a "pymongo-$pkgver" "pymongo2-$pkgver"
}

package_python2-pymongo() {
  depends=('python2')

  cd "$srcdir/pymongo2-$pkgver"
  python2 setup.py install --root="$pkgdir" --optimize=1
}

package_python-pymongo() {
  depends=('python')

  cd "$srcdir/pymongo-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1
}

# vim:set ts=2 sw=2 et:
sha512sums=('6da3cbf035b52379c24df37b76e1eb743b12c1026116e28e4e7b6450e2674d730f9c8c2dd85f352c6ee4c9f604decaffc2dbc57fe64268bd7522d8ce155cca9e')