# $Id: PKGBUILD 106958 2014-03-10 22:32:08Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: David Moore <davidm@sjsoft.com>

pkgbase=python-simplejson
pkgname=("$pkgbase" 'python2-simplejson')
pkgver=3.3.3
pkgrel=1
pkgdesc='Simple, fast, extensible JSON encoder/decoder for Python'
license=('MIT')
arch=('x86_64' 'i686')
url='http://undefined.org/python/#simplejson'
makedepends=('python-setuptools' 'python2-setuptools')
source=("$pkgname-$pkgver.tar.gz::https://github.com/simplejson/simplejson/tarball/v${pkgver}")
sha256sums=('3c1ea4826afdbbb2e8f589540772f8b06ea2a81f575db1edde84fc1829bb293b')

package_python-simplejson() {
  depends=('python')

  cd "simplejson-simplejson-"*
  python setup.py install --root="$pkgdir"
  install -Dm644 "$srcdir/simplejson-simplejson"-*/LICENSE.txt \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-simplejson() {
  depends=('python2')

  cd "simplejson-simplejson-"*
  python2 setup.py install --root="$pkgdir"
  install -Dm644 "$srcdir/simplejson-simplejson"-*/LICENSE.txt \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et: