# $Id: PKGBUILD 63722 2012-02-05 12:09:17Z ibiru $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Giovanni Scafora <linuxmania@gmail.com>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=qcad
pkgver=2.0.5.0
pkgrel=9
pkgdesc="A 2D CAD package based upon Qt"
arch=('i686' 'x86_64')
url="http://www.ribbonsoft.com/qcad.html"
license=('GPL2')
depends=('qt3')
options=(libtool)
source=(http://www.ribbonsoft.com/archives/$pkgname/$pkgname-$pkgver-1-community.src.tar.gz
        qcad.xpm
        QCad.desktop
        qcad-intptr.patch
        qcad.patch)
       # http://ghost1227.com/files/misc/qm.tar.gz)
md5sums=('96b6a56027782aec953c9c4e64c5998c'
         'da32fec0d2fb85d96126bf28bb0ab9ff'
         'b4d1eb6724b4b41f191f1ab6fd859c39'
         '92f900fe1fd3a8f841232b587b49c7da'
         '7e6779b1e3b10da1eb4daf36d93f8479')

build() {
  export PATH="/opt/qt/bin:$PATH"
  export QTDIR=/opt/qt

  cd ${srcdir}/${pkgname}-2.0.5.0-1-community.src

  #Arch64 fix - gentoo patch
  [ "$CARCH" = "x86_64" ] && patch -p1 < ../qcad-intptr.patch
  patch -p1 < ../qcad.patch
  sed -i "s:"-pedantic"::g" mkspecs/defs.pro

  cd scripts
  ./build_qcad.sh notrans
}

package() {
  cd ${srcdir}/${pkgname}-2.0.5.0-1-community.src/qcad

  install -D -m755 qcad ${pkgdir}/usr/bin/qcad
  install -d ${pkgdir}/usr/share/{qcad,pixmaps,applications}
  install -m644 ../../qcad.xpm ${pkgdir}/usr/share/pixmaps/qcad.xpm
  install -m644 ../../QCad.desktop \
    ${pkgdir}/usr/share/applications/QCad.desktop
  cp -r fonts patterns data library machines ${pkgdir}/usr/share/qcad
  #cp -r ${srcdir}/qm ${pkgdir}/usr/share/qcad/
}