# $Id: PKGBUILD 51336 2011-07-07 21:24:31Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Matthias Maennich <arch@maennich.net>
# Contributor: <boenki@gmx.de>

pkgname=qlandkartegt
pkgver=1.2.1
pkgrel=1
pkgdesc="Use your GPS with Linux"
arch=('i686' 'x86_64')
url="http://www.qlandkarte.org/"
license=('GPL')
depends=('gdal' 'gpsd' 'libdmtx' 'libexif' 'libmysqlclient' 'mesa' 'postgresql-libs' 'qt' 'shared-mime-info')
makedepends=('cmake' 'garmindev')
optdepends=('garmindev: to connect garmin devices')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz
        $pkgname-mimetypes.xml)
sha256sums=('24304fb148651e1e989ff9c15e56e3c6fb5d8b1e16aa70342d73bee86be67da8'
            'e8d33948831f8a66edd752c71c653085d6c4d9f1969e70dd8c40b9c7ca37fba0')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  install -d ${srcdir}/$pkgname-$pkgver/build
  cd ${srcdir}/$pkgname-$pkgver/build

  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release ..
  make
}

package(){
  cd ${srcdir}/$pkgname-$pkgver/build

  make DESTDIR=${pkgdir} install

  install -D -m644 ${srcdir}/$pkgname-mimetypes.xml \
    ${pkgdir}/usr/share/mime/packages/$pkgname-mimetypes.xml
}