# $Id: PKGBUILD 79252 2012-11-01 19:02:54Z mtorromeo $
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>

pkgname=quassel
pkgver=0.8.0
pkgrel=2
pkgdesc="QT4 irc client with a separated core"
arch=('i686' 'x86_64')
url="http://quassel-irc.org/"
license=('GPL')
depends=('kdebase-runtime')
makedepends=('cmake' 'automoc4')
install=quassel.install
backup=(etc/conf.d/quassel)
source=("http://quassel-irc.org/pub/$pkgname-$pkgver.tar.bz2"
        'quassel.service'
        'rc.quassel'
        'quassel.conf')
sha256sums=('a3515bd18e2b100eb9a72480e76b1faefaa5e84cdb236b6af1f05b477a1e9071'
            '91a1aaae47d41c11aa418dd560039ddbbfb659e02b86379d8c4789c5ada362d3'
            '845e621448a51ec181554e9327bfcc3a3de1501ae8f70410f0b9b8991ac171b0'
            'f3031ea8217e01ba42cea14606169e3e27affa5918968ffd5a03c21ae92fe2b8')

build() {
  [[ ! -d build ]] && mkdir build
  cd build

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr/ \
    -DWITH_KDE=1 \
    -DCMAKE_BUILD_TYPE="Release" \
    ../${pkgname}-${pkgver}/ \
    -Wno-dev

  make
}

package() {
  cd build

  make DESTDIR="${pkgdir}" install

  install -Dm644 "${srcdir}"/$pkgname.service \
    "${pkgdir}"/usr/lib/systemd/system/$pkgname.service
  install -D "${srcdir}"/rc.$pkgname \
    "${pkgdir}"/etc/rc.d/$pkgname
  install -Dm644 "${srcdir}"/$pkgname.conf \
    "${pkgdir}"/etc/conf.d/$pkgname
}