# $Id: PKGBUILD 87393 2013-03-30 17:15:21Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>

pkgbase=signon
pkgname=('signon' 'signon-doc')
pkgver=8.49
pkgrel=1
pkgdesc="Framework to provide credential storage and authentication service"
arch=('i686' 'x86_64')
url="http://code.google.com/p/accounts-sso/"
license=('LGPL')
depends=('qt4' 'libproxy')
makedepends=('doxygen' 'graphviz' 'ttf-dejavu')
backup=(etc/signond.conf)
install=$pkgname.install
source=(http://accounts-sso.googlecode.com/files/$pkgbase-$pkgver.tar.bz2
        use_keyring.patch)
sha1sums=('349d700eed718977463020f252269786883bc4c6'
          'cfdd48b494ad267654ceba23f1b81bcb8f56b9a1')

build() {
  cd "$srcdir/$pkgbase-$pkgver"

  # Use gnome-keyring secrets storage if signon-keyring-extension is available
  patch -Np1 -i "$srcdir/use_keyring.patch"

  # qt4 fix
  sed -i 's/qdbusxml2cpp/qdbusxml2cpp-qt4/' src/signond/signond.pro

  qmake-qt4 PREFIX=/usr LIBDIR=/usr/lib
  make
}

package_signon() {
  cd "$srcdir/$pkgbase-$pkgver"

  make INSTALL_ROOT="$pkgdir" install

  # Split out documentation
  mv "$pkgdir/usr/share/doc" "$srcdir"
}

package_signon-doc() {
  pkgdesc="Developer documention of signon"
  depends=()
  options=('!emptydirs')
  backup=()
  install=

  mkdir -p "$pkgdir/usr/share"
  mv "$srcdir/doc" "$pkgdir/usr/share"
}