# $Id: PKGBUILD 66543 2012-02-26 00:22:29Z lfleischer $
# Maintainer: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Anton Bazhenov <anton.bazhenov at gmail>

pkgname=udunits
pkgver=2.1.24
pkgrel=1
pkgdesc='A tool for calculations of physical quantities'
arch=('i686' 'x86_64')
url='http://www.unidata.ucar.edu/software/udunits/'
license=('custom')
options=('!libtool')
depends=('glibc' 'expat')
provides=('udunits2')
install=udunits.install
source=("ftp://ftp.unidata.ucar.edu/pub/$pkgname/$pkgname-$pkgver.tar.gz")
md5sums=('6986545721747a51285c765644dcd9d8')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # stupid workaround for broken make install
  install -dm755 "$pkgdir/usr/share/doc/$pkgname"

  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  for x in so so.0 so.0.1.0; do
    ln -s "libudunits2.$x" "$pkgdir/usr/lib/libudunits.$x"
  done

  install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}