# $Id: PKGBUILD 90107 2013-05-06 19:40:06Z foutrelis $
# Maintainer: Sébastien Luttringer
# Contributor: Joel Teichroeb <joel@teichroeb.net>

pkgname=weston
pkgver=1.1.0
pkgrel=2
pkgdesc='Reference implementation of a Wayland compositor'
arch=('i686' 'x86_64')
url='http://wayland.freedesktop.org'
license=('MIT')
options=(!libtool)
depends=('libxkbcommon' 'libunwind' 'poppler-glib' 'mtdev' 'libxcursor' 'glu' 'pango')
source=("http://wayland.freedesktop.org/releases/$pkgname-$pkgver.tar.xz")
sha1sums=('0929afa86d795e0e970936623d86bdd950d48e8d')

build() {
	cd $pkgname-$pkgver
	./configure \
		--prefix=/usr \
		--libexecdir=/usr/lib/weston \
		--disable-android-compositor
	make
}

package() {
	cd $pkgname-$pkgver
	make DESTDIR="$pkgdir" install
	# license
	install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
	# embed more clients
	for _c in calibrator clickdot cliptest dnd editor eventdemo flower gears image \
	 resizor simple-egl simple-shm simple-touch smoke transformed view; do
		install -Dm755 "clients/$_c" "$pkgdir/usr/bin/weston-$_c"
	done
	for _c in info keyboard screensaver screenshooter tablet-shell terminal; do
		install -Dm755 "clients/weston-$_c" "$pkgdir/usr/bin/weston-$_c"
	done
}