# $Id: PKGBUILD 110070 2014-04-23 17:10:36Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: Jason Chu <jason@archlinux.org>

pkgname=xdiskusage
pkgver=1.48
pkgrel=8
pkgdesc="xdiskusage is a user-friendly program to show you what is using up all your disk space"
arch=('i686' 'x86_64')
depends=('fltk')
makedepends=('libxi')
license=('GPL')
url="http://xdiskusage.sourceforge.net"
options=(!emptydirs)
source=(http://xdiskusage.sourceforge.net/$pkgname-$pkgver.tgz
	'build-fix.patch')
md5sums=('a902aa9d73761ade98256c3cd5c1f533'
         '570eb00cb0999231620b67889325a81f')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/build-fix.patch"
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -d "$pkgdir/usr/bin" "$pkgdir/usr/share/man/man1"
  make prefix="$pkgdir/usr" mandir="$pkgdir/usr/share/man" install
  chmod 0644 $pkgdir/usr/share/man/man1/*
}