# $Id: PKGBUILD 110078 2014-04-23 17:30:12Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Kritoke <kritoke@nospam.gmail.com>
# Contributor: Kritoke <kritoke@nospam.gmail.com>

pkgname=xmms-imms
pkgver=301
pkgrel=1
pkgdesc="An intelligent playlist plug-in for XMMS that tracks your listening patterns and dynamically adapts to your taste."
arch=(i686 x86_64)
license=("GPL")
url="http://imms.luminal.org/"
depends=('xmms' 'pcre' 'sqlite' 'taglib' 'glib2' 'sox' 'torch' 'libxss' 'fftw')
replaces=('imms')
source=(http://imms.googlecode.com/files/imms-r${pkgver/_/-}.tar.bz2)
md5sums=('8b3dfac2ce1ae988a7c2fbc47026cc73')

build() {
  cd $srcdir/imms-r${pkgver/_/-}
  autoheader
  aclocal
  autoconf
  ./configure --prefix=/usr --disable-immsremote
  make LDFLAGS="-L. -lXss -lXext -lX11 -lsqlite3 -lz  -lpcre  -ltag -L/usr/X11R6/lib /usr/lib/libtorch.so.3"
}

package() {
  cd $srcdir/imms-r${pkgver/_/-}
  mkdir -p $pkgdir/usr/bin
  make prefix=$pkgdir/usr DESTDIR=$pkgdir/usr/lib/xmms/General \
	 BMPDESTDIR=$pkgdir/usr/lib/bmp/General install
}