# $Id: PKGBUILD 212061 2014-05-05 21:10:41Z seblu $
# Maintainer: Sébastien "Seblu" Luttringer
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>

pkgname=btrfs-progs
pkgver=3.14.1
pkgrel=1
pkgdesc='Btrfs filesystem utilities'
arch=('i686' 'x86_64')
depends=('glibc' 'e2fsprogs' 'lzo2' 'zlib')
makedepends=('git')
url='http://btrfs.wiki.kernel.org/'
replaces=('btrfs-progs-unstable')
conflicts=('btrfs-progs-unstable')
provides=('btrfs-progs-unstable')
license=('GPL2')
source=("git://git.kernel.org/pub/scm/linux/kernel/git/mason/${pkgname}.git#tag=v${pkgver}"
        'initcpio-install-btrfs'
        'initcpio-hook-btrfs')
install=btrfs-progs.install
options=(!staticlibs)
md5sums=('SKIP'
         '7241ba3a4286d08da0d50b7176941112'
         'b09688a915a0ec8f40e2f5aacbabc9ad')

build() {
   cd $pkgname
   make CFLAGS="$CFLAGS"
   make CFLAGS="$CFLAGS" btrfs-select-super
}

package() {
   cd $pkgname

   make prefix="$pkgdir"/usr install
   install -Dm755 btrfs-select-super "$pkgdir"/usr/bin

   # fix manpage
   install -d "$pkgdir"/usr/share/
   mv "$pkgdir"/usr/man "$pkgdir"/usr/share/man

   # install mkinitcpio hooks
   cd "$srcdir"
   install -Dm644 initcpio-install-btrfs "$pkgdir/usr/lib/initcpio/install/btrfs"
   install -Dm644 initcpio-hook-btrfs "$pkgdir/usr/lib/initcpio/hooks/btrfs"
}

# vim:set ts=2 sw=2 ft=sh et: