# $Id: PKGBUILD 160921 2012-06-07 02:05:22Z pierre $
# Maintainer:
# Contributor: Simo Leone <simo@archlinux.org>
# Contributor: Tobias Kieslich <tobias@justdreams.de>

pkgname=aspell-de
pkgver=20120607
pkgrel=1
pkgdesc="German dictionary for aspell"
arch=('i686' 'x86_64')
url="http://j3e.de/ispell/igerman98/index.html"
license=('GPL2')
depends=('aspell')
source=("http://j3e.de/ispell/igerman98/dict/igerman98-${pkgver}.tar.bz2")
md5sums=('9433d0ccd7db3c7681037980ece3f710')

build() {
  cd "${srcdir}/igerman98-${pkgver}"

  LANGS="de_DE de_AT de_CH"
  for l in ${LANGS}; do
    make aspell/${l}.rws
  done
}

package() {
  cd "${srcdir}/igerman98-${pkgver}/aspell"

  install -d "${pkgdir}/usr/lib/aspell-0.60"

  LANGS="de_DE de_AT de_CH"
  for l in ${LANGS}; do
    install -m644 ${l}.alias ${l}.dat ${l}_affix.dat ${l}.multi ${l}.rws \
      "${pkgdir}/usr/lib/aspell-0.60/"
  done

  echo "add de_DE.multi" > "${pkgdir}/usr/lib/aspell-0.60/deutsch.alias"
  echo "add de_DE.multi" > "${pkgdir}/usr/lib/aspell-0.60/german.alias"
  echo "add de_CH.multi" > "${pkgdir}/usr/lib/aspell-0.60/swiss.alias"
}