# $Id: PKGBUILD 194508 2013-09-17 02:50:40Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

pkgname=cogl
pkgver=1.14.0
pkgrel=5
pkgdesc="An object oriented GL/GLES Abstraction/Utility Layer"
arch=('i686' 'x86_64')
url="http://www.clutter-project.org/"
license=('GPL2')
depends=('libdrm' 'libxext' 'libxdamage' 'libxcomposite' 'gdk-pixbuf2' 'pango')
makedepends=('mesa' 'gobject-introspection')
options=(!libtool !emptydirs)
source=(http://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        git-fixes.patch)
sha256sums=('276e8c9f5ff0fcd57c1eaf74cc245f41ad469a95a18ac831fac2d5960baa5ae8'
            '5f9279122cabf5cce23c1e19cedd9e67231f63a4d35329924b256fc1adc1aab2')

prepare() {
  cd "$pkgname-$pkgver"
  # Update to ba5e5410babf705f53b591579c104181dd752bec
  # Removed version parts from configure.ac and .gitignore parts, removed conflicting it.po and eu.po commits
  patch -Np1 -i ../git-fixes.patch
}

build() {
  cd "$pkgname-$pkgver"
  autoreconf -fi
  ./configure --prefix=/usr \
    --enable-wayland-egl-platform --enable-gles{1,2}

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: