# $Id: PKGBUILD 139655 2011-10-04 13:22:43Z andyrtr $
# Maintainer: Andreas Radke <andyrtr at archlinux.org>
# Contributor: Thomas Baechler <thomas.baechler@rwth-aachen.de>

pkgname=cups-pdf
pkgver=2.6.0
pkgrel=2
pkgdesc="PDF printer for cups"
arch=(i686 x86_64)
depends=('cups' 'ghostscript')
install=cups-pdf.install
url="http://cip.physik.uni-wuerzburg.de/~vrbehr/cups-pdf"
license=('GPL2')
source=(http://cip.physik.uni-wuerzburg.de/~vrbehr/cups-pdf/src/cups-pdf_$pkgver.tar.gz)
backup=(etc/cups/cups-pdf.conf)
md5sums=('8ee644c77438aac542301352266db181')
sha1sums=('45ecff78f26dab6261bbf66978e708d93385ef31')

build() {
  cd $srcdir/$pkgname-$pkgver/src
  [ -z "$CC" ] && CC=gcc
  $CC $CFLAGS -Wall -o cups-pdf cups-pdf.c
}

package() {
  cd $srcdir/$pkgname-$pkgver/src
  install -D -m700 cups-pdf $pkgdir/usr/lib/cups/backend/cups-pdf

  # Install Postscript Color printer
  cd ../extra
  install -D -m644 CUPS-PDF.ppd $pkgdir/usr/share/cups/model/CUPS-PDF.ppd

  # Install config file
  install -D -m644 cups-pdf.conf $pkgdir/etc/cups/cups-pdf.conf
  # fix https://bugs.archlinux.org/task/26243
  sed -i "s:e  cups-pdf.conf:#  cups-pdf.conf:g"  $pkgdir/etc/cups/cups-pdf.conf
}