# $Id: PKGBUILD 197914 2013-10-30 11:39:08Z allan $
# Maintainer: Ronald van Haren <ronald@archlinux.org>
# Contributor: Gustavo Sverzut Barbieri <barbieri@gmail.com>

pkgname=e_dbus
pkgver=1.7.8
pkgrel=1
pkgdesc="D-Bus integration with Ecore"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('BSD')
depends=('ecore' 'dbus-core')
options=('!emptydirs')
source=(http://download.enlightenment.org/releases/$pkgname-$pkgver.tar.gz)
sha1sums=('726b2c4259e8818921ce0c27a3d452d414255975')

build() {
  cd $srcdir/$pkgname-$pkgver

  export CFLAGS="-fvisibility=hidden -ffunction-sections -fdata-sections ${CFLAGS}"
  export CXXFLAGS="-fvisibility=hidden -ffunction-sections -fdata-sections ${CXXFLAGS}"
  export LDFLAGS="-fvisibility=hidden -ffunction-sections -fdata-sections -Wl,--gc-sections -Wl,--as-needed  ${LDFLAGS}"

  ./configure \
    --prefix=/usr \
    --disable-static \
    --disable-ebluez \
    --disable-econnman0_7x \
    --disable-ehal \
    --enable-enotify \
    --disable-eofono \
    --enable-eukit \
    --disable-edbus-test \
    --disable-edbus-test-client \
    --disable-edbus-bluez-test \
    --disable-edbus-connman0_7x-test \
    --disable-edbus-ofono-test \
    --disable-edbus-async-test \
    --disable-edbus-performance-test \
    --disable-doc
  make
}

package(){
  cd $srcdir/$pkgname-$pkgver

  make DESTDIR=$pkgdir install

  # install license files
  install -Dm644 $srcdir/$pkgname-$pkgver/COPYING \
        $pkgdir/usr/share/licenses/$pkgname/COPYING
}