# $Id: PKGBUILD 185674 2013-05-16 20:57:59Z ronald $
# Maintainer: Ronald van Haren <ronald@archlinux.org>
# Contributor: Gustavo Sverzut Barbieri <barbieri@gmail.com>

pkgname=emotion
pkgver=1.7.7
pkgrel=1
pkgdesc="Library to easily integrate media playback into EFL applications"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('BSD')
depends=('gstreamer0.10' 'edje' 'eeze')
options=('!libtool' '!emptydirs')
source=(http://download.enlightenment.org/releases/$pkgname-$pkgver.tar.gz)
sha1sums=('e42b73a268afaa022efb179966991cfb3865168b')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  export CFLAGS="-fvisibility=hidden -ffunction-sections -fdata-sections ${CFLAGS}"
  export CXXFLAGS="-fvisibility=hidden -ffunction-sections -fdata-sections ${CXXFLAGS}"
  export LDFLAGS="-fvisibility=hidden -ffunction-sections -fdata-sections -Wl,--gc-sections -Wl,--as-needed  ${LDFLAGS}"

  ./configure \
    --prefix=/usr \
    --disable-static \
    --enable-generic \
    --enable-gstreamer \
    --disable-generic-vlc \
    --disable-xine \
    --disable-install-examples \
    --disable-doc
  make
}

package(){
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install

  # install license files
  install -Dm644 $srcdir/$pkgname-$pkgver/COPYING \
        $pkgdir/usr/share/licenses/$pkgname/COPYING
}