# $Id: PKGBUILD 188094 2013-06-09 11:29:56Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>

pkgname=gnome-bluetooth
pkgver=3.8.1
pkgrel=2
pkgdesc="The GNOME Bluetooth Subsystem"
arch=(i686 x86_64)
url="http://live.gnome.org/GnomeBluetooth"
license=(GPL LGPL)
depends=(gtk3 hicolor-icon-theme libnotify bluez4)
makedepends=(intltool gobject-introspection itstool docbook-xsl)
options=(!libtool !emptydirs)
install=gnome-bluetooth.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        61-gnome-bluetooth-rfkill.rules)
sha256sums=('8095fcfa014931773e9d231dff76c6924f43abfbe4c5525cf07fd2d7f8e1f770'
            '8dd2d3637f380a89e72f65e6c8021e994ccbdc645f1a1b1dbffe74ac9f061f53')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --disable-desktop-update \
    --disable-icon-update \
    --disable-schemas-compile

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -m644 -D ../61-gnome-bluetooth-rfkill.rules \
      "$pkgdir/usr/lib/udev/rules.d//61-gnome-bluetooth-rfkill.rules"
}