# $Id: PKGBUILD 213468 2014-05-23 23:35:41Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-chess
pkgver=3.12.2
pkgrel=1
pkgdesc="Play the classic two-player boardgame of chess"
arch=('i686' 'x86_64')
license=('GPL')
depends=('desktop-file-utils' 'hicolor-icon-theme' 'gtk3' 'librsvg' 'glu')
makedepends=('intltool' 'itstool' 'gobject-introspection')
optdepends=('gnuchess: Play against computer')
conflicts=('gnome-games')
replaces=('gnome-games')
options=('!emptydirs')
install=gnome-chess.install
url="https://live.gnome.org/Chess"
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('381e9f0b8ff470fd2df57b836c89e6a26ff10a6c885ddd3358b89b015b03147e')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --disable-schemas-compile
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}