# $Id: PKGBUILD 211868 2014-04-28 15:11:59Z jgc $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>

pkgname=gnome-color-manager
pkgver=3.12.1
pkgrel=2
pkgdesc="Color profile manager for the GNOME desktop"
arch=(i686 x86_64)
url="http://projects.gnome.org/gnome-color-manager/"
license=(GPL2)
depends=(libcanberra vte3 exiv2 hicolor-icon-theme desktop-file-utils shared-color-targets colord-gtk libexif)
makedepends=(intltool yelp-tools)
optdepends=('argyllcms: color calibration')
install=gnome-color-manager.install
options=('!emptydirs')
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('06bbc4ce1cd7862a33c6b8d64e647770936cf8787756135b0781385bac1998a9')

build(){
  cd $pkgname-$pkgver

  # man pages need docbook-sgml, which we don't have
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --libexecdir=/usr/lib/gnome-color-manager --disable-static --disable-man-pages

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}