# $Id: PKGBUILD 148440 2012-01-31 22:33:21Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-games
pkgver=3.2.1
pkgrel=2
pkgdesc="Some Games for GNOME"
arch=('i686' 'x86_64')
license=('GPL')
depends=('libsm' 'gconf' 'desktop-file-utils' 'libcanberra' 'clutter-gtk' 'hicolor-icon-theme' 'librsvg' 'python2-gobject' 'dconf')
makedepends=('gnome-doc-utils' 'intltool' 'gobject-introspection')
options=('!emptydirs' '!libtool')
install=gnome-games.install
url="http://www.gnome.org"
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        gnome-sudoku-fix.patch)
sha256sums=('b40fe59537fd58af1bd8163897684883b730ee0f0257d23b493b13e21d105a3b'
            '00daafd11078355e16f384fe98dab69ee7e03037c8c311e7180f8f896965a715')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/gnome-sudoku-fix.patch"
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-scrollkeeper \
      --disable-static \
      --with-scores-user=root --with-scores-group=games \
      --enable-introspection=yes
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make -j1 GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install

  # Remove all scores, we generate them from postinstall
  rm -rf "$pkgdir/var"

  install -m755 -d "$pkgdir/usr/share/gconf/schemas"
  gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" --domain gnome-games "$pkgdir"/etc/gconf/schemas/*.schemas
  rm -f "$pkgdir"/etc/gconf/schemas/*.schemas

  sed -i 's_#! /usr/bin/env python_#!/usr/bin/env python2_' "$pkgdir/usr/bin/gnome-sudoku"
}