# $Id: PKGBUILD 126303 2011-06-04 12:33:16Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-power-manager
pkgver=3.0.2
pkgrel=2
pkgdesc="Session daemon that makes it easy to manage your laptop or desktop system."
arch=(i686 x86_64)
url="http://www.gnome.org/projects/gnome-power-manager/"
license=('GPL')
depends=('libnotify' 'gconf' 'libcanberra' 'gnome-icon-theme' 'upower'
         'libgnome-keyring' 'dconf')
makedepends=('intltool' 'gnome-doc-utils' 'gnome-control-center')
options=(!emptydirs)
install=gnome-power-manager.install
groups=(gnome)
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2
        fix-suspend.patch)
sha256sums=('d0e00fdcfbc3bfb709f9ed82a14de325c51cf0bb86eeacefcda2dd7fcf6cbc2b'
            '898454c9a22ecdf56e555687d4d41a0dfa3d590408dc2a17ef6cf4eaec83b262')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i "${srcdir}/fix-suspend.patch"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var \
      --libexecdir=/usr/lib/gnome-power-manager \
      --disable-scrollkeeper \
      --with-dbus-services=/usr/share/dbus-1/services \
      --disable-schemas-compile
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}