# $Id: PKGBUILD 23389 2009-01-09 00:47:54Z eric $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>

pkgname=kobodeluxe
pkgver=0.5.1
pkgrel=2
pkgdesc="An enhanced version of Akira Higuchi's game XKobo, an addictive space shoot'em up"
arch=('i686' 'x86_64')
url="http://www.olofson.net/kobodl/"
license=('GPL' 'LGPL')
depends=('gcc-libs' 'libjpeg' 'libpng' 'sdl' 'sdl_image' 'sdl_mixer')
install=kobodeluxe.install
source=(http://www.olofson.net/kobodl/download/KoboDeluxe-${pkgver}.tar.gz kobodeluxe-gcc-4.3.patch)
md5sums=('cf765559461213d651c7be042507b767' '2b76306ec997fdc64986b4425e5b7814')
sha1sums=('12abe182ccde52050cd23077092d0424d25c3e75' '274dc8e7909bc6f9fab31306c85d992af8b62674')

build() {
  cd ${srcdir}/KoboDeluxe-${pkgver}
  patch -p0 < ../kobodeluxe-gcc-4.3.patch
  ./configure --prefix=/usr --localstatedir=/var --sharedstatedir=/var/games || return 1
  make || return 1
  make DESTDIR=${pkgdir} install || return 1
 
  tar -xzf icons.tar.gz
  install -D -m644 icons/KDE/kobo-deluxe.desktop ${pkgdir}/usr/share/applications/kobo-deluxe.desktop
  install -D -m644 icons/KDE/icons/128x128/kobodl.png ${pkgdir}/usr/share/icons/hicolor/128x128/kobodl.png
  install -D -m644 icons/KDE/icons/16x16/kobodl.png ${pkgdir}/usr/share/icons/hicolor/16x16/kobodl.png
  install -D -m644 icons/KDE/icons/22x22/kobodl.png ${pkgdir}/usr/share/icons/hicolor/22x22/kobodl.png
  install -D -m644 icons/KDE/icons/32x32/kobodl.png ${pkgdir}/usr/share/icons/hicolor/32x32/kobodl.png
  install -D -m644 icons/KDE/icons/48x48/kobodl.png ${pkgdir}/usr/share/icons/hicolor/48x48/kobodl.png
  install -D -m644 icons/KDE/icons/64x64/kobodl.png ${pkgdir}/usr/share/icons/hicolor/64x64/kobodl.png
  install -D -m644 icons/Ubuntu/kobo-icon.xpm ${pkgdir}/usr/share/pixmaps/kobo-icon.xpm
  ln -s /usr/share/icons/hicolor/48x48/kobodl.png ${pkgdir}/usr/share/icons/kobodl.png

  chown root:games ${pkgdir}/usr/bin/kobodl
  chmod 2755 ${pkgdir}/usr/bin/kobodl
  chown root:games ${pkgdir}/var/games
  chmod 775 ${pkgdir}/var/games
  chown root:games ${pkgdir}/var/games/kobo-deluxe
  chmod 775 ${pkgdir}/var/games/kobo-deluxe
  chown root:games ${pkgdir}/var/games/kobo-deluxe/scores
  chmod 775 ${pkgdir}/var/games/kobo-deluxe/scores
}