# $Id: PKGBUILD 211682 2014-04-23 06:32:53Z lcarlier $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=libxfont
pkgver=1.4.7
pkgrel=2
pkgdesc="X11 font rasterisation library"
arch=(i686 x86_64)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('freetype2' 'libfontenc' 'xproto' 'fontsproto')
makedepends=('xorg-util-macros' 'xtrans')
source=(${url}/archive/individual/lib/libXfont-${pkgver}.tar.bz2
	fix-for-fontsproto213.patch)
sha256sums=('d16ea3541835d296b19cfb05d7e64fc62173d8e7eb93284402ec761b951d1543'
            '9c8298cc9f4dc3981f19107353b2e4373dfb7882768bbf0b3ae027820a2dcad9')

prepare() {
  cd "${srcdir}/libXfont-${pkgver}"
  # FS#40044 - merged for branch 1.5
  patch -Np1 -i ../fix-for-fontsproto213.patch
}

build() {
  cd "${srcdir}/libXfont-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static
  make
}

package() {
  cd "${srcdir}/libXfont-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}