# $Id: PKGBUILD 212349 2014-05-13 19:35:10Z lcarlier $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=libxfont
pkgver=1.4.7
pkgrel=3
pkgdesc="X11 font rasterisation library"
arch=(i686 x86_64)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('freetype2' 'libfontenc' 'xproto' 'fontsproto')
makedepends=('xorg-util-macros' 'xtrans')
source=(${url}/archive/individual/lib/libXfont-${pkgver}.tar.bz2
	fix-for-fontsproto213.patch
	CVE-2014-209-210-211.patch)
sha256sums=('d16ea3541835d296b19cfb05d7e64fc62173d8e7eb93284402ec761b951d1543'
            '9c8298cc9f4dc3981f19107353b2e4373dfb7882768bbf0b3ae027820a2dcad9'
            '9e70cafaf67636baea1295027d4bb197a74a8ac8469674e4be5776dd27b1741a')

prepare() {
  cd "${srcdir}/libXfont-${pkgver}"
  # FS#40044 - merged for branch 1.5
  patch -Np1 -i ../fix-for-fontsproto213.patch
  # fix CVE-2014-209 CVE-2014-210 CVE-2014-211 - merged upstream
  patch -Np1 -i ../CVE-2014-209-210-211.patch
}

build() {
  cd "${srcdir}/libXfont-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static
  make
}

package() {
  cd "${srcdir}/libXfont-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}