# $Id: PKGBUILD 98524 2010-11-10 22:12:25Z angvp $
# Maintainer: Angel 'angvp' Velasquez <angvp@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
# Contributor: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor: Dan McGee <dpmcgee@gmail.com>
pkgname=monotone
pkgver=0.99.1
pkgrel=1
pkgdesc="A modern distributed version control system, like hg, darcs, or git"
arch=('i686' 'x86_64')
url="http://www.monotone.ca"
license=('GPL')
depends=('botan' 'pcre' 'lua' 'sqlite3' 'libidn' 'zlib')
makedepends=('boost')
install=${pkgname}.install
source=(http://www.monotone.ca/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz)
md5sums=('61c586f340fa3ca2b0974f6b5c455b0e')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  install -Dm644 contrib/monotone.bash_completion \
    "${pkgdir}/etc/bash_completion.d/monotone"
  install -Dm644 contrib/monotone.zsh_completion \
    "${pkgdir}/usr/share/zsh/site-functions/monotone"
}