# $Id: PKGBUILD 94910 2010-10-12 12:58:13Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: damir <damir@archlinux.org>

pkgname=netcdf
pkgver=4.1.1
pkgrel=3
pkgdesc="network Common Data Form interface for array-oriented data access and corresponding library"
arch=("i686" "x86_64")
url="http://www.unidata.ucar.edu/downloads/netcdf/index.jsp"
depends=('gcc-libs' 'hdf5' 'gcc-fortran')
options=('force' '!libtool' '!makeflags')
license=('custom')
source=(http://www.unidata.ucar.edu/downloads/netcdf/ftp/netcdf-${pkgver}.tar.gz)
sha1sums=('6fece208825b978fc2240732f6f57927d71a0552')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure --prefix=/usr --enable-shared --enable-netcdf-4
  make
  make check
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  install -m755 -d ${pkgdir}/usr/lib
  install -m755 -d ${pkgdir}/usr/share/man
  make DESTDIR=${pkgdir} install

  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/COPYRIGHT \
	${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT
}