# $Id: PKGBUILD 203485 2014-01-11 17:11:51Z bisson $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor : shining <shiningxc.at.gmail.com>
# Contributor : cyberdune <cyberdune@gmail.com>

pkgname=octave
pkgver=3.6.4
pkgrel=6
pkgdesc="A high-level language, primarily intended for numerical computations."
arch=('i686' 'x86_64')
url="http://www.octave.org"
license=('GPL')
depends=('fftw' 'curl' 'graphicsmagick' 'glpk' 'hdf5' 'qhull' 'fltk' 'arpack' 'glu') 
makedepends=('gcc-fortran' 'texlive-core' 'suitesparse')
optdepends=('texinfo: for help-support in octave'
            'gnuplot: alternative plotting')
source=(ftp://ftp.gnu.org/gnu/octave/octave-$pkgver.tar.bz2{,.sig}
        mex-gcc-4.8.patch)
options=('!emptydirs')
install=octave.install
sha1sums=('3cc9366b6dbbd336eaf90fe70ad16e63705d82c4'
          'SKIP'
          '0608af9b7ccce8455f534d2fc4acf2f4c8f83a60')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # https://savannah.gnu.org/bugs/?38746
  patch -Np1 -i "${srcdir}/mex-gcc-4.8.patch"
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  autoreconf -vfi

  ./configure --prefix=/usr --libexecdir=/usr/lib \
  --enable-shared --disable-static \
  --with-quantum-depth=16 \
  --with-umfpack="-lumfpack -lsuitesparseconfig" # https://mailman.cae.wisc.edu/pipermail/help-octave/2012-September/053991.html

  LANG=C make
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  # add octave library path to ld.so.conf.d
  install -d "${pkgdir}/etc/ld.so.conf.d"
  echo "/usr/lib/${pkgname}/${pkgver}" > "${pkgdir}/etc/ld.so.conf.d/${pkgname}.conf"
}