# $Id: PKGBUILD 151921 2012-03-04 10:39:20Z andrea $
# Maintainer:
# Contributor: Kevin Piche <kevin@archlinux.org>
# Contributor: Eddie Lozon <almostlucky@attbi.com>

pkgname=pekwm
pkgver=0.1.14
pkgrel=1
pkgdesc="A small, fast, functional, and flexible window manager"
arch=('i686' 'x86_64')
license=('GPL')
url='https://www.pekwm.org/projects/pekwm'
depends=('gcc-libs' 'libjpeg' 'libpng' 'libxft' 'libxinerama' 'libxpm' 'libxrandr')
backup=(etc/pekwm/config
  etc/pekwm/vars
  etc/pekwm/autoproperties
  etc/pekwm/start
  etc/pekwm/keys
  etc/pekwm/mouse
  etc/pekwm/menu)
source=("http://www.pekwm.org/projects/pekwm/files/${pkgname}-${pkgver}.tar.bz2"
        'pekwm.desktop')
md5sums=('bb9c01c81fe47620bcd9be0e2e4a10e6'
         '5a78fc6653fbb0b7282ecf7f1f81e2c5')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  # Default settings:
  #    --enable-shape --enable-xinerama --enable-menus \
  #    --enable-harbour --disable-debug --disable-pedantic \
  #    --enable-xft --enable-image-xpm --enable-image-jpeg \
  #    --enable-image-png --enable-xrandr
  ./configure --prefix=/usr --sysconfdir=/etc

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m644 "${srcdir}/${pkgname}.desktop" \
                   "${pkgdir}/usr/share/xsessions/${pkgname}.desktop"
}
# vim: ts=2 sw=2 et ft=sh