# $Id: PKGBUILD 138532 2011-09-27 03:18:03Z eric $
# Maintainer:
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=proftpd
pkgver=1.3.3f
pkgrel=1
pkgdesc="A high-performance, scalable FTP server"
arch=('i686' 'x86_64')
url="http://www.proftpd.org"
license=('GPL')
depends=('libldap' 'libmysqlclient' 'postgresql-libs')
backup=('etc/proftpd.conf' 'etc/conf.d/proftpd')
source=("ftp://ftp.proftpd.org/distrib/source/${pkgname}-${pkgver}.tar.bz2"
        'proftpd' 'proftpd.logrotate' 'proftpd.conf.d')
md5sums=('e9416d2aa7ac1246af4fc8a80fd73f27'
         '99f6f9a989e70e3fa50809fc2bbbbb0a'
         'ddb09eb13131becdf0e081eef413116b'
         '71d5932b0461c318ed68c2c0c2660736')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr \
    --mandir=/usr/share/man \
    --disable-pam \
    --with-modules=mod_quotatab:mod_quotatab_sql:mod_quotatab_file:mod_tls:mod_ldap:mod_sql:mod_sql_mysql:mod_sql_postgres \
    --sysconfdir=/etc \
    --localstatedir=/var/run \
    --enable-ctrls \
    --enable-ipv6 \
    --with-includes=/usr/include/mysql:/usr/include/postgresql \
    --with-libraries=/usr/lib/mysql:/usr/lib/postgresql \
    --enable-nls

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
  install -Dm644 ../proftpd.logrotate "${pkgdir}/etc/logrotate.d/proftpd"
  install -Dm644 ../proftpd.conf.d "${pkgdir}/etc/conf.d/proftpd"
  install -Dm755 ../proftpd "${pkgdir}/etc/rc.d/proftpd"
  install -Dm755 contrib/xferstats.holger-preiss "${pkgdir}/usr/bin/ftpstats"

  cd "${pkgdir}/etc"
  sed -i 's|nogroup|nobody|g' proftpd.conf
  rmdir "${pkgdir}/usr/libexec"
}