# $Id: PKGBUILD 110756 2011-02-22 02:50:48Z stephane $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=python-cairo
pkgver=1.8.10
pkgrel=2
pkgdesc="Python bindings for the cairo graphics library"
arch=('i686' 'x86_64')
license=('LGPL3')
depends=('python' 'cairo')
makedepends=('pkg-config')
options=('!libtool')
source=(http://cairographics.org/releases/pycairo-${pkgver}.tar.bz2
        pycairo-1.8.10-pypath.patch)
url="http://www.cairographics.org/pycairo"
md5sums=('ddc544943d791e3c22ca8f019e10e1e3'
         '047cfe0a98cfa73a156cd70e70082325')

build() {
  cd "${srcdir}/pycairo-${pkgver}"

  # We patch the embedded copy of waf to fix compiling against python 3.2
  # (due to PEP-3149), by using the appropriate python-config tool, rather
  # than trying to find the libraries by directly using PYTHON_VERSION

  # Ensure that ./waf has created the cached unpacked version
  # of the wafadmin source tree.
  # This will be created to a subdirectory like
  #    .waf3-1.5.18-a7b91e2a913ce55fa6ecdf310df95752
  python ./waf --version

  # Patch the unpacked version of waf:
  pushd .waf3*
  patch -Np0 -i ../../pycairo-1.8.10-pypath.patch
  popd

  ./waf configure --prefix=/usr
  ./waf build
}

package() {
  cd "${srcdir}/pycairo-${pkgver}"
  ./waf install --destdir="${pkgdir}"
}