# $Id: PKGBUILD 109447 2011-02-09 17:52:06Z schiv $
# Maintainer: Ray Rashif <schivmeister@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Robert Emil Berge <robert@rebi.no>

pkgname=rosegarden
pkgver=11.02
pkgrel=1
pkgdesc="MIDI/audio sequencer and notation editor"
arch=('i686' 'x86_64')
url="http://www.rosegardenmusic.com/"
license=('GPL')
depends=('liblrdf' 'dssi' 'fftw' 'lirc-utils'
         'perl' 'qt' 'shared-mime-info')
makedepends=('pkgconfig' 'imake')
optdepends=('lilypond: notation display'
            'cups: printing support'
            'okular: print preview, or any other PDF viewer'
            'timidity++: MIDI playback, or any other softsynth'
            'flac'
            'wavpack')
[ "$CARCH" = "i686" ] && optdepends=("${optdepends[@]}"
                                     'dssi-vst: win32 VST support')
install=$pkgname.install
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
md5sums=('fca86bfd7351a16cc2b55a85d2c8a128')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et: