# $Id: PKGBUILD 204061 2014-01-15 08:53:01Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Laurent Carlier <lordheavym@gmail.com>

pkgname=telepathy-kde-accounts-kcm
_pkgname=ktp-accounts-kcm
pkgver=0.7.1
pkgrel=1
pkgdesc="KCM Module for configuring Telepathy Instant Messaging Accounts"
arch=('i686' 'x86_64')
url="http://community.kde.org/Real-Time_Communication_and_Collaboration"
license=('GPL')
depends=('telepathy-kde-common-internals' 'telepathy-kde-contact-list')
makedepends=('cmake' 'automoc4' 'boost')
optdepends=('telepathy-gabble: XMPP/Jabber/GTalk support'
            'telepathy-haze: all protocols supported by libpurple')
groups=('kde-telepathy')
conflicts=('telepathy-kde-accounts-kcm-plugins')
replaces=('telepathy-kde-accounts-kcm-plugins')
source=("http://download.kde.org/stable/kde-telepathy/${pkgver}/src/${_pkgname}-${pkgver}.tar.bz2")
sha1sums=('483f0013d6d847ad9ee666d65cf971c1565bc6a8')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../${_pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}