# $Id: PKGBUILD 154456 2012-03-28 18:51:17Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Tobias Kieslich <tobias (at) archlinux.org>

pkgname=thunar-volman
pkgver=0.6.1
pkgrel=1
pkgdesc="Automatic management of removeable devices in Thunar"
arch=('i686' 'x86_64')
url="http://foo-projects.org/~benny/projects/thunar-volman"
license=('GPL2')
groups=('xfce4-goodies')
depends=('thunar' 'libxfce4ui' 'hicolor-icon-theme')
makedepends=('intltool')
options=('!libtool')
install=$pkgname.install
source=(http://archive.xfce.org/src/apps/$pkgname/0.6/$pkgname-$pkgver.tar.bz2)
sha256sums=('04918a9ccd576e7b19dae37af50ffe6de6f79ed66bf305c26dfe81c1ff652b27')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib/xfce4 \
    --localstatedir=/var \
    --disable-static \
    --disable-debug
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: