# $Id: PKGBUILD 138508 2011-09-26 12:20:21Z guillaume $
# Maintainer: Guillaume ALAUX <guillaume at archlinux dot org>
# Contributor: Hugo Doria <hugo@archlinux.org>
pkgname=tomcat
pkgver=5.5.34
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="Servlet-2.4/JSP-2.0 Container"
url="http://tomcat.apache.org/"
license=('APACHE')
depends=('java-environment')
makedepends=('openjdk6')
backup=('opt/tomcat/conf/server.xml' 'opt/tomcat/conf/tomcat-users.xml' 'etc/conf.d/tomcat')
install=tomcat.install
source=(http://archive.apache.org/dist/tomcat/tomcat-5/v${pkgver}/bin/apache-tomcat-${pkgver}.tar.gz
	'tomcat'
	'tomcat.conf.d')
md5sums=('d09a09bc84409510574a673d35939f16'
         '20e6a8e89a148e2b0ac81ca03ceea6b1'
         '368322d8a51ce20cc5dbdb505706a16a')

build() {
  unset LDFLAGS
  # build jsvc
  cd ${srcdir}/apache-${pkgname}-${pkgver}/bin
  tar xzf commons-daemon-native.tar.gz
  cd commons-daemon-1.0.7-native-src/unix
  sh configure --with-java=/usr/lib/jvm/java-6-openjdk
  make clean
  make
  cp jsvc ../..
}

package() {
  cd ${srcdir}/apache-${pkgname}-${pkgver}/bin
  # get rid of some cruft
  cd ${srcdir}/apache-${pkgname}-${pkgver}
  rm -f LICENSE NOTICE RELEASE-NOTES RUNNING.txt
  rm -fr bin/*.exe bin/*.bat bin/*.tar.gz bin/jsvc-src

  # install everything
  mkdir -p ${pkgdir}/opt/tomcat
  cp -R * ${pkgdir}/opt/tomcat
  install -D -m755 ${srcdir}/tomcat ${pkgdir}/etc/rc.d/tomcat
  install -D -m644 ${srcdir}/tomcat.conf.d ${pkgdir}/etc/conf.d/tomcat
  chgrp -R 66 ${pkgdir}/opt/tomcat/{conf,work,webapps,logs}
  chmod 0660 ${pkgdir}/opt/tomcat/conf/{*.xml,*.policy,*.properties,/Catalina/localhost/*.xml}
  chmod 775 ${pkgdir}/opt/tomcat/{conf,work,webapps,logs}
}