# $Id: PKGBUILD 140583 2011-10-17 08:15:09Z jgc $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan Jezek <honzin.jezek@gmail.com>

pkgname=tumbler
pkgver=0.1.22
pkgrel=3
pkgdesc="D-Bus service for applications to request thumbnails"
url="http://git.xfce.org/xfce/tumbler/"
license=('GPL2' 'LGPL')
arch=('i686' 'x86_64')
groups=('xfce4')
depends=('poppler-glib' 'dbus-glib' 'bzip2' 'gdk-pixbuf2')
makedepends=('intltool' 'ffmpegthumbnailer' 'gstreamer0.10')
optdepends=('ffmpegthumbnailer:	for video thumbnails'
            'gstreamer0.10: for video thumbnails')
options=('!libtool')
source=(http://archive.xfce.org/src/apps/${pkgname}/0.1/${pkgname}-${pkgver}.tar.bz2
        fix-video-image.patch)
md5sums=('e7ba3b8f21f8f7e736f1e214906b4ca9'
         'be9b0f1c3a4b0be102774c84d5ac29e6')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i ../fix-video-image.patch
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--libexecdir=/usr/lib/xfce4 \
	--disable-static \
	--disable-debug
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}