# $Id: PKGBUILD 203642 2014-01-13 17:13:28Z andyrtr $
#Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=xf86-video-v4l
pkgver=0.2.0
pkgrel=13
pkgdesc="X.org v4l video driver"
arch=(i686 x86_64)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=('glibc')
makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=15')
conflicts=('xorg-server<1.15.0' 'X-ABI-VIDEODRV_VERSION<15' 'X-ABI-VIDEODRV_VERSION>=16')
groups=('xorg-drivers' 'xorg')
source=(${url}/releases/individual/driver/${pkgname}-${pkgver}.tar.bz2
        git-fixes.patch
        LICENSE)
md5sums=('2251ae2a0a905764941cd7b098e85ad1'
         'cdb7113a9564ea9202e847de88440540'
         '7d4d018f6bbff7e42672d1aabc75c5cf')

build() {
  cd ${pkgname}-${pkgver}
  patch -Np1 -i "${srcdir}/git-fixes.patch"
  autoreconf -fi
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/"
}