# $Id: PKGBUILD 186157 2013-05-21 10:21:01Z foutrelis $
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>

pkgname=xfce4-dict
pkgver=0.7.0
pkgrel=1
pkgdesc="A dictionary plugin for the Xfce panel"
arch=('i686' 'x86_64')
url="http://goodies.xfce.org/projects/applications/xfce4-dict"
license=('GPL2')
groups=('xfce4-goodies')
depends=('xfce4-panel' 'librsvg' 'hicolor-icon-theme')
makedepends=('intltool')
provides=('xfce4-dict-plugin')
conflicts=('xfce4-dict-plugin')
replaces=('xfce4-dict-plugin')
options=('!libtool')
install=$pkgname.install
source=(http://archive.xfce.org/src/apps/$pkgname/0.7/$pkgname-$pkgver.tar.bz2)
sha256sums=('407fc0f02adf6ea85dec6993db1e222b548afcdd63a9e35ed2d70a42c9738e58')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --localstatedir=/var \
    --disable-static \
    --disable-debug
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: